Modification of copy paste vba code

[Leonardo1234]

Const START_COL_ORIG As Integer = 1
Const START_COL_DEST As Integer = 2
Const SHEET_ORIG As String = "Sheet1"
Const SHEET_DEST As String = "Sheet2"

Public Sub STEP3()
   Dim shOrig As Worksheet, shDest As Worksheet
  
   Application.ScreenUpdating = False
  
   Set shOrig = Worksheets(SHEET_ORIG)
   Set shDest = Worksheets(SHEET_DEST)
   shOrig.Select
   Application.Union(shOrig.Columns(START_COL_ORIG), shOrig.Columns(START_COL_ORIG + 1)).Select
   Selection.Copy
   shDest.Activate
   shDest.Cells(1, START_COL_DEST).Select
   ActiveSheet.Paste
   Application.CutCopyMode = False
  
   Application.ScreenUpdating = True
End Sub

This vba codes copy column A & B from sheet1 and paste to column B & C in sheet2
what i need in this is copy column A,B,C,D,E from sheet1 and paste to sheet2 in column B,C,D,E,F

 

[bobhc]

Please use code tags as requested in the box just above where you enter your question.

 

[Belleke]

Try this

Const START_COL_ORIG As Integer = 1
Const START_COL_DEST As Integer = 2
Const SHEET_ORIG As String = "Sheet1"
Const SHEET_DEST As String = "Sheet2"
Public Sub STEP3()
Dim shOrig As Worksheet, shDest As Worksheet
Application.ScreenUpdating = False
Set shOrig = Worksheets(SHEET_ORIG)
Set shDest = Worksheets(SHEET_DEST)
With shOrig
Application.Union(.Columns(START_COL_ORIG), .Columns(START_COL_ORIG + 1), .Columns(START_COL_ORIG + 2) _
, .Columns(START_COL_ORIG + 3), .Columns(START_COL_ORIG + 4)).Copy
End With
shDest.Activate
shDest.Cells(1, START_COL_DEST).Select
ActiveSheet.Paste
With Application
.CutCopyMode = False
.ScreenUpdating = True
End With
End Sub

 

[p45cal]

Const START_COL_ORIG As Integer = 1
Const START_COL_DEST As Integer = 2
Const SHEET_ORIG As String = "Sheet1"
Const SHEET_DEST As String = "Sheet2"

Public Sub STEP3()
Dim shOrig As Worksheet, shDest As Worksheet

Application.ScreenUpdating = False

Set shOrig = Worksheets(SHEET_ORIG)
Set shDest = Worksheets(SHEET_DEST)

shOrig.Range("A:E").Copy shDest.Range("B1")

Application.ScreenUpdating = True
End Sub

In such a short macro, thre's really no need to assign the sheets to variables; this is a bit more efficient:

Public Sub STEP3()
Application.ScreenUpdating = False
Worksheets(SHEET_ORIG).Range("A:E").Copy Worksheets(SHEET_DEST).Range("B1")
Application.ScreenUpdating = True
End Sub

And using your constants:

Public Sub STEP3()
Application.ScreenUpdating = False
  Worksheets(SHEET_ORIG).Columns(START_COL_ORIG).Resize(, 5).Copy Worksheets(SHEET_DEST).Cells(1, START_COL_DEST)
Application.ScreenUpdating = True
End Sub

 

[Leonardo1234]

Sorry for that i will use code tags in future
Thnx p45cal,Belleke,bobhc for giving ur precious time and great support to this post

 

[Hui]

Code tags are used like this: