show hours of commission of work list according to the selected name

[Visor]

Dear friends of the forum, thank you very much for helping me in this problem.
I have a matrix with the names in the rows and the beads in the hives and the inside I have the corresponding working hours.
I have in O5 the Selection by commission, to do so the formulas shows me the list of names of professionals who have the same commission of work. Along the formulas show me the hours of work that each teacher has in the commission of work.

On the other hand in R5 the selection by names and surnames where the formulas show me the list of which the teacher has. Here is the problem, the formula to display the hours of that job commission (cell S7 with red fill) I can not get it to show.
Why can you help me in correcting the formula to show the hours in S7 cell?
thanks in advance

 

[bosco_yip]

Try......

1] P7, copied down :

=IF(O7="","",INDEX(D$7:L$29,MATCH(O7,B$7:B$29,0),MATCH(O$5,D$5:L$5,0)))

2] S7, copied down :

=IF(R7="","",INDEX(D$7:L$29,MATCH(R$5,B$7:B$29,0),MATCH(R7,D$5:L$5,0)))

Regards
Bosco

 

[Visor]

First, thank you for your kind cooperation. Then tell you that the formula is great, it is more understandable, the truth that with the form you have given me I stay, to use it.

However, I am a person that I like to get to the bottom in certain things, and is that the terrible and extensive formula placed in P7 to extract the hours when I select in O5 the job commission works well!
I do not understand why the similar formula in S7 (when I select Names) could not work equally ????
What is wrong???

 

[bosco_yip]

.......
I do not understand why the similar formula in S7 (when I select Names) could not work equally ???? What is wrong???

Hi,

1] Here's the fixing of your formula in S7.

Your S7 formula :

=IFERROR(INDEX($D$5:$L$5,,AGGREGATE(15,6,COLUMN($D$5:$L$5)-3/(INDEX($D$7:$L$29,MATCH($R$5,$B$7:$B$29,),)<>""),ROWS($A$1:$A1)),MATCH($R$5,$B$7:$B$29,0)),"")

My revised S7 formula :

=IFERROR(INDEX($D$7:$L$29,MATCH($R$5,$B$7:$B$29,0),AGGREGATE(15,6,COLUMN($D$5:$L$5)-3/(INDEX($D$7:$L$29,MATCH($R$5,$B$7:$B$29,),)<>""),ROWS($A$1:$A1))),"")

2] See attached file

Regards
Bosco

 

[Visor]

oooooh practically with this ROWS ($ A $ 1: $ A1), finished everything
You're great!!!
amazing
I put too many things in the formula that had me stunned
Thanks for your support you got me out of a mess
Topic solved